% Routines for the METAFONT logo
% (logo10.mf is a typical parameter file)
mode_setup;
ygap#:=(ht#/13.5u#)*xgap#;        % vertical adjustment
leftstemloc#:=2.5u#+s#;           % position of left stem
barheight#:=.45ht#;               % height of bar lines
define_pixels(s,u,xgap,ygap,leftstemloc,barheight);
py#:=.9px#; define_blacker_pixels(px,py); % pen dimensions
pickup pencircle xscaled px yscaled py; logo_pen:=savepen;
define_corrected_pixels(o);

beginchar("E",14u#+2s#,ht#,0);
pickup logo_pen;
x1=x2=x3=leftstemloc;
x4=x6=w-x1+o; x5=x4-xgap;
y1=y6; y2=y5; y3=y4;
bot y1=0; top y3=h;
y2=barheight;
draw z6--z1--z3--z4; draw z2--z5;
labels(1,2,3,4,5,6);
endchar;

beginchar("F",14u#+2s#,ht#,0);
pickup logo_pen;
x1=x2=x3=leftstemloc;
x4=w-x1+o; x5=x4-xgap;
y2=y5; y3=y4;
bot y1=0; top y3=h;
y2=barheight;
draw z1--z3--z4; draw z2--z5;
labels(1,2,3,4,5);
endchar;

beginchar("M",18u#+2s#,ht#,0);
pickup logo_pen;
x1=x2=leftstemloc; x4=x5=w-x1+o;
bot y1=bot y5=0; top y2=top y4=h;
x3=.5[x1,x5]; y3-y1=ygap;
draw z1--z2--z3--z4--z5;
labels(1,2,3,4,5);
endchar;

beginchar("T",13u#+2s#,ht#,0);
pickup logo_pen;
x1=leftstemloc;
x2=w-x1+o; top y1=top y2=h;
z3=.5[z1,z2];
x3=x4; bot y4=0;
draw z1--z2; draw z3--z4;
labels(1,2,3,4);
endchar;

%ligtable "T": "A" kern -.5u#;
%ligtable "F": "O" kern -u#;

font_quad  18u#+2s#;
font_normal_space  6u#+2s#;
font_normal_stretch  3u#;
font_normal_shrink  2u#;